NWP1-Anwendungsstatistik erweitern

Mit Hinweis 1609418 aus 2011 wurde der Klinische Arbeitsplatz (NWP1) dahingehend erweitert, dass im Verlauf der Anwendung zusätzliche Informationen in die Anwendungsstatistik (Transaktion STAD) protokolliert werden. (Beachten Sie, dass Sie je nach Ihrem Systemzustand die Korrektur aus Hinweis 2193204 einbauen müssen, um die Protokollierung einschalten zu können.) Die so protokollierte Information ist zwar nützlich, aber für Performance-Untersuchungen leider nicht ausreichend.

Der Grund liegt im Umfang der protokollierten Informationen. Dazu noch einmal Hinweis 1609418:

In der Spalte 'Application Info' wird

  • bei Aufruf einer Sicht der dazugehörige Sichttyp und die Sicht-Id in einem String angezeigt (z.B. 007/CSTPRI0001).

Wenn man den Klinischen Arbeitsplatz konfiguriert, versucht man normalerweise, Varianten und Sichtdefinitionen soweit wie möglich wiederzuverwenden, um die Wartung zu vereinfachen. Das bedeutet, dass eine Sichtdefinition (die über Sichttyp und ID wie oben angegeben eindeutig identifiziert wird) in beliebig vielen Arbeitsumfeldern verwendet werden kann. Einige Sichttypen können zur Selektion zusätzlich auf Daten aus der Arbeitsumfelddefinition zurückgreifen, was wiederum bedeutet, dass ein und dieselbe Sichtdefinition je nach umgebendem Arbeitsumfeld sehr verschiedene Datenmengen selektieren und sehr unterschiedliches Laufzeitverhalten zeigen kann. Zusammengefasst: Um Sichten zu identifizieren, die oft benötigt werden und/oder von Performance-Verbesserungen profitieren würden, ist der Sicht-Schlüssel nicht ausreichend - man braucht auch den Arbeitsumfeld-Schlüssel.

Nach Rücksprache mit SAP Support sind derzeit keine Änderungen der Protokollierung geplant. Da die Protokollierung allerdings über einen zentralen Funktionsbaustein namens ISH_WP_ASTAT_WRITE erfolgt, kann man mit einer relativ einfachen Erweiterung die zusätzlichen Informationen ablegen.

FUNCTION ish_wp_astat_write.                     "note 1609418  
ENHANCEMENT 1 ZZZ_ISH_WP_ASTAT_WRITE.     
  DATA: l_wplace_id_1 TYPE nwplaceid,  
        l_wplace_id_2 TYPE nwplaceid,  
        l_wplace_id   TYPE nwplaceid,  
        l_view_id_1   TYPE nviewid,  
        l_view_id_2   TYPE nviewid,  
        l_view_type_1 TYPE nviewtype,  
        l_view_type_2 TYPE nviewtype,  
        l_app_info    type CHAR50.  
  IF i_openkey = 'NWP1_CALL_VIEW'.  
    " determine the workplace ID  
    CALL FUNCTION 'ISH_WP_ACTIVE_VIEWS_TRANSFER'  
      IMPORTING  
        e_wplace_id  = l_wplace_id_1  
        e_view_id    = l_view_id_1  
        e_view_type  = l_view_type_1  
        e_wplace_id2 = l_wplace_id_2  
        e_view_id2   = l_view_id_2  
        e_view_type2 = l_view_type_2.  
    IF i_view_type = l_view_type_1 AND i_view_id = l_view_id_1.  
      l_wplace_id = l_wplace_id_1.  
    ELSEIF i_view_type = l_view_type_2 AND i_view_id = l_view_id_2.  
      l_wplace_id = l_wplace_id_2.  
    ENDIF.  
    IF l_wplace_id IS NOT INITIAL.  
      CONCATENATE l_wplace_id i_view_type i_view_id INTO l_app_info SEPARATED BY '/'.  
      "           ^^^^^^^^^^^ new  
      CALL FUNCTION 'PF_ASTAT_OPEN'  
        EXPORTING  
          openkey = i_openkey  
          appinfo = l_app_info.  
      CALL FUNCTION 'PF_ASTAT_CLOSE'  
        EXPORTING  
          openkey = i_openkey.  
      RETURN. " --> leave function module to suppress default processing  
    ENDIF.  
  ENDIF.  
ENDENHANCEMENT.  

Mit dieser Erweiterung protokolliert das System jetzt auch die Arbeitsumfeld-ID (z. B. 'CSTPRI001234/007/CSTPRI0001').

Theme by Danetsoft and Danang Probo Sayekti inspired by Maksimer